型態

型態(Types)

在這一章中我們介紹Object Pascal 中的型態宣告，告訴你基本的型態定義，有結構的型態及型態間的關聯。

型態宣告(type declaration)

在Object Pascal中，每一個變數在使用前都必需先宣告它的型態，一個變數可以做那些運箅，可以儲存什麼樣的資料，都是由它的型熊來決定的。除了Object Pascal已經宣告的一些基本型態外，我們也可以視需要定義出自己需要的型態。
讓我們先看看型態宣告的例子:
type
ScoreRange=0..100 ;
string20=string[20] ;
ErrorList=array[0..20] of string20 ;
Season=(spring, summer, autumn , winter) ;

保留字type後面的宣告，代表我們自行定義的型態類別。請注意，在這裏宣告的不是變數，而是一種型態，本身並不佔用記憶體，必須等到宣告這一種型態的變數產生後，才會向系統要求記憶體來儲存變數的資料。最後，也是最重要的，總是要有一些最基本的型態，我們才能再加以變化出我們所需要的東西。底下我們就從Object Pascal已經定義好的型態開始介紹起.

簡單型態(simple types)
這一類的型態包含有整數(integer)、實數(real)、字元(character)、列舉(enumerated)、布林(boolean)及子範圍(subrange)等七種型態。除了實數外，其餘六種我們也稱為序數型態(ordinal types)，序數型態最主要的特性就是具有順序性，值的大小就代表其順序，通常除了序數本身的意義外，我們也經常利用序數這種特性，把它拿來當索引使用，我們晚一點會介紹實際的例子。底下還是先介紹簡單型態。
整數型態
部份型態是與作業環境相關，在16位元版本和32位元版本下所能使用的儲存格式不同, 我們稱為一般型態(Generic Types)。而與作業環境無關的，我們稱為基礎型態(Fundamental Types)。各種整數型態的名稱及其數值範圍整理如下:
基礎型態
型態名稱    最小值    最大值     使用位元組
byte    0    255    1
shortint    -128    127    1
smallint    -32768    32767    2
word    0    65535    2
longint    -2147483648    2147483647    4

一般型態在Delphi 16位元版本下
型態名稱    最小值    最大值     使用位元組
integer    -32768    32767    2
cardinal    0    65535    2

一般型態在Delphi 32位元版本下
型態名稱    最小值    最大值     使用位元組
integer    -2147483648    2147483647    4
cardinal    0    2147483647    4

實數型態
這一類的型態會有精確度上的限制，因為使用浮點數(floating-point)來記錄數值, 所以在做運算時，會有一定程度的誤差。例如有可能會以0.99999999來代替1.00000000。關於各種浮點數的儲存格式，請自行參考相關書籍。各種實數型態的名稱及其數值範圍整理如下:

型態名稱    最小值    最大值     有效位數    使用位元組
single    1.5*10^-45    3.4 * 10^38    7-8     4
real    2.9 * 10^-39    1.7 * 10^38    11-12     6
double    5.0 * 10^-324    1.7 * 10^308     15-16    8
comp    - 2^63 + 1    2^63 - 1    19-20     8
currency    - (2^63) * 10^-4    (2^63 - 1) * 10^-4     19-20    8
extended    3.4 * 10^-4392    1.1 * 10^4932     19-20    10

O real 是為了相容性的考量而存在，因為所使用的格式在Intel系列的CPU上需要經過轉換才能運算，所以運算的速度比較慢。
O comp只能記錄整數。
O currency是為了金額計算上的準確度而定義出來的型態。採用定點數(fixed-point)資料型態。真正在運算時是先乘上10000，將數值轉為整數後再做計算, 再回存時才除上10000，因此不會產生近似值誤差。在Delphi 2.0 之後才提供currency型態。
O 上表除了comp和currency外，最小值這一欄所列的數值為正數最小值，實際上的最小值應為最大值這一欄所列的數值乘上-1。

字元型態
字元型態和整數型態同樣有一般型態及基礎型態的區分。
基礎型態AnsiChar與WideChar分別使用單、雙位元組來儲存資料。AnsiChar的範圍就是我們一般使用的ASCII 0..255。WideChar則是使用Unicode字元集合的順序。
一般型態char一直到Delphi 2.0仍使用AnsiChar來代表其意義。

不管是任何資料型態，若要取得資料型態所使用的記憶體大小時，可以使用標準函數sizeof。如此可避免程式在移轉作業平台時，產生計算上的錯誤。
列舉型態
在說明什麼是列舉型態前, 讓我們來看看下面這個型態宣告:
type
Week=(Sun, Mon, Tue, Wed, Thu, Fri, Sat) ;

在這裏我們宣告一個名稱為Week 的型態，在這種型態中包含有七種元素，這七個元表是有順序性的，我們可以使用ord這個標準函數來取得元素在這個型態中的位置，在第一個位置的元素傳回值是0，例如ord(Sun)傳回0、ord(Fri)傳回5。
真正的程式實作中, 使用列舉型態並不會增加程式的速度或減少程式所佔的空間，它的價值在於增進程式的可讀性。列舉型態有點像是常數，加強了撰寫程式的便利，但是對程式的執行效能沒有什麼影響。

布林型態(boolean types)
布林型態主要用於程式流程的判斷(迴圈、條件判斷)。在布林型態中只有兩種值--true和false，在不同類型的布林型態中，對true和false的定義不太相同，下表列出了它們的差異:

型態名稱    False    True    型態定義     使用位元組
Boolean    false    true    列舉型態     1
ByteBool    0    非0    byte     1
WordBool    0    非0    word     2
LongBool    0    非0    longint     4

在程式的實作中，用得最多，也最省記憶體的應該就是boolean，其它三種主要是為了與其它程式語言相容的考量而保留的。

子範圍型態(subrange types)
一個子範圍型態是一個主範圍型態(host type)中的一部份，必需是連續的序數並設定最小值和最大值，除此之外它具有一切和主範圍型態相同的性質。底下就是一些子範圍型態的範例:
type
ScoreRange=0..100 ;
UpperCase='A'..'Z' ;
WorkDay=Mon..Fri ;

上述的例子中，分別用整數、字元和列舉定義出新的子範圍型態。不過有一點要注意，只有在編譯時打開編譯選項Range Checking(在Options/Project/Compiler下)或使用編譯指令{$R+}才會真正去檢查範圍，否則即使指定一個超過範圍的數值，也不會產生錯誤訊息。

字串型態(string types)
在16位元版本的Delphi中，只有一種短字串(Short Strings)的格式，到了32位元版本後，才又多提供了長字串(Long Strings)的功能。字串型態由保留字string所宣告的。在32位元版本的Delphi中, 因為有長字串及短字串兩種型態，所以有一個編譯指令{$H+}表示string代表宣告長字串(預設值)，{$H-}則表示宣告為短字串。以下我們分別介紹二者的不同。
短字串
短字串除了可以用string來宣告外，也可使用Delphi事先定義的型態ShortString(32位元版本才有)。它的長度必須介於0到255之間，我們在宣告的時候，可以先決定字串的最大長度(預設為255)，下為宣告限定長度短字串的範例:
type
string10=string[10] ;
string100=string[100] ;

上面所宣告的string10和string100分別代表最大長度為10和100的短字串，若指定一個超過最大長度的字串，則超過的部份將會被捨棄。
一個短字串所佔用的記憶體包含一個位元組來記錄字串的長度(這也就是為什麼短字串最多只能有255個字元的原因)，因此一個短字串佔用的記憶體為 (宣告長度+1) 。
我們可以使用索引的方式取出字串中的個別字元。讓我們先看看下面這個程式片斷:
{$H-}
function rtrim(s:string):string ;
var
I : integer ;
begin
I:=ord(s[0]) ;        // 取出字串長度, 和 I:=length(s)效果相同
while s[I]=#32 do    // 當字串的最後一個字元為空白字元(ASCII 32)
I:=I-1 ;            // 字串長度減一
s[0]:=chr(I) ;        // 將去除尾端空白後的字串長度寫回索引值0
Result:=s ;        // 傳回去除尾端空白的字串
end ;

上面這個函數，是針對短字串的特性所寫的。索引值0的位元組記錄著這個字串目前的長度(不可大於宣告時指定的長度，不指定則是255)，由字串中最後一個字元開始比較, 直到不是空白字元時，直接將字串長度寫入索引值0的位置就可改變字串的長度了。
使用索引方式要注意一件事，編譯器並不會檢查你所取出的字元是不是在宣告的範圍內。因此當存取到起過範圍的字元時，程式並不會出現錯誤，但無法預期會產生什麼結果。
在長字串中，因為並沒有一個位元直接記著字串的長度，所以就無法使用類似的方法。接下來我們就開始介紹長字串的特性。
長字串
由於不再使用一個位元組來記錄字串長度，長字串的最大長度理論上可以長達2GB(GigaBytes)，足可滿足各類的需要。
除了保留字string外，也可以用另一個系統定義好的識別字AnsiString來宣告長字串型態。我們將長字串的一些特性整理如下:
O 長字串是採用動態記憶體配置，不用宣告最長長度，系統會自動處理相關的運算。一個長字串變數佔用了四個位元組以指向所配置的記憶體，當指定一個新的值給長字串時，系統只是改變指標位置並攻有真正的複製字元，所以長字串在指定值的時候通常都比短字串快。
O 有可能多個長字串變數指到同一塊記憶體，因此Delphi使用參考計數的方法來處理。當指定一個新的值給長字串時，系統會將指向那一塊記憶體的參考計數加一，反之原來舊值的參考計數器則減一。當參考計數器為零的時候，這一塊記憶體就釋回給系統。
O 當使用索引的方式改變字串內容時，如果參考計數大於一，則系統會先複製一份字串再更改內容，以避免影響到其他的變數，這種方法稱為copy-on-write。
O 當一個長字串剛產生時，都會被設成一個空字串。
O 當長字串的生命週期結束時，不管是因為什麼原因，參考計數器都會自動減一。
O 要取得或設定長字串的長度，必須使用標準的Pascal指令length和SetLentgh。
O 長字串不能使用var的參數傳遞方式，也不能出現在一個記錄型態的變動部份。(原因都是因為長字串只是一個指標。)
O 長字串會自動最後一個字元後加上空字元(ASCII 0)，所以要轉換成Pchar型態時，只要加上型別轉換就可以了。

在指定和運算式中，長字串和短字串可以混合使用，但是在被當成參數傳遞時則需區分清楚。
字串的比較是由相對應位置的字元來決字串的順序，請參考下列的例子:
'AB' < 'BB' ;        // 正確
'AA' < 'AAAa' ;    // 正確
'ABC' < 'abc' ;    // 正確

在Object Pascal Language Guide的第5章中還會介紹到字串的運算及比較，關於字串我們就先討論到這裏為止。

結構型態(structure types)
一個能擁有一個以上數值的型態，我們稱為結構型態。在結構型態中也可以有更下一層的結構。理論上一個結構型態中可以有無限多個結構階層。
關鍵字packed 可以使結構型態佔用較少的空間，當然代價就是存取時可能要花上較多的時間。
底下介紹陣列、記錄、集合、檔案這四種結構型態，至於類別(class)及類別參考(class reference)這兩種結構型態，在Object Pascal Language Guide的第9章中有詳細的討論。
陣列型態(array types)
在開始介紹陣列型態之前，讓我們先看一些宣告的範例:
type
Secs=array[0..59] of integer ;
Mins=array[0..59] of Secs ;
InSeat=array['A'..'Z'] of boolean ;
MyRect=array[1..2,1..2] of integer ;
Poly=packed array[60,1..2] of integer ;

陣列擁有固定數目的指定型態，以保留字array來宣告，後面用中括號內含索引的範圍，接著用保留字of來指定陣列元素的型態(component type)。陣列的維度(dimension)並沒有限制，且所有的序數型態都可以拿來設定索引範圍。
陣列本身也可以當成是一種元素，所以可以如Mins這樣宣告。存取這種多層陣列的方式，我們還會在下一章提到。
記錄型態(record types)
在陣列中雖然有多個元素，但每一個元素的型態都是相同的。若要在同一個的結構下有多種型態的元素存在，就必需使用記錄型態。
記錄型態用保留字record來宣告，範例如下:
type
Employ=record
Name : string ;
Marry : boolean ;
Salary : currency ;
end ;
Car=record
year:1900..2100 ;
case accident:boolean of
false: (loss:currency; Damage:boolean) ;
true: (hodometer:double; insure:curreny) ;
end ;
end ;

上面宣告了兩個記錄型態Employ和Car，二者最大的不同在於car中多了一個變動欄位(variant)，case用來區分不同的標籤欄位識別字(tag field identifier)所代表的欄位，這些欄位可能會用到共同一塊記憶體，在執行時程式會依照標籤欄位的值來決定要如何取用這一個記錄的內容。

集合型態(set types)
集合是序數型態的元素所組合而成，且在一個集合之中的元素型態必須相同。保留字set用來宣告集合型態，如下例:
type
Week=(Sun, Mon, Tue, Wed, Thu, Fri, Sat) ;
Grade=set of 'A'..'E' ;
Today=set of Week ;

集合的範圍中不可以超過256個元素，且序數的數值必須介於0..255之間。一個不包含任何數值的集合，稱之為空集合。
關於集合的運算，我們在這裏暫不討論。

檔案型態(file types)
檔案型態使用保留字file宣告。可以在後面接著一種元素型態(檔案型態除外)來指定最小的存取單位。
type
f1 : file ;
f2 : file of char ;
f3 : file of double ;
f4 : textfile ;

文字檔(textfile)是一種特殊的檔案型態，會自動處理部份控制字元(換行字元、檔案結尾)。檔案型態涉及到檔案系統的運作，這一部份可以參考Object Pascal Language Guide的第13章, 裏頭有更深入的說明。

指標(pointer types)
指標事實上只是一組數字，記錄著真正存放資料的位址。一般稱這種記錄方式為"指向"，所以我們慣用 "指向xxxx的指標" 來說明指標中記錄的位址代表的型態。
指標型態主要是運用在動態變數(dynamic variable)中，所謂的動態變數在程式執行中才取得一塊記憶體來使用，當不再需要這塊記憶體來儲存資料時，則將這一塊記憶體歸還給系統。
Delphi事先定義了兩種指標型態: pointer和pchar，此外也可以宣告自訂的指標型態。讓我們先看下面這一段程式宣告的片段:
type
WordP=^word ;        // 用word 型態作為基底型態(base type)
Link=^MyObject ;    // 自訂記錄型態 MyObject 做為基底型態
MyObject=record
data : longint ;
Next : Link ;
end ;

向上的箭頭(^，ASCII 94)代表這是一個指標型態，後面緊接著基底型態(base type)，也就是決定它所指向的那一塊記憶體是用那一種型態來儲存資料的。
一個指標在取出它所指向的資料前，必需先決定所指向的是什麼型態。pointer和其它的指標型態有一個不同，它是一個不指向任何特定型態的指標，所以宣告成pointer型態的變數不能直接使用指標符號(^)取出它指向的內容。不過pointer和其它的指標型態相容，也就是說可以先做型態轉換(typecast)，再存取所指向的資料。
pchar在system單元中宣告如下
type
PAnsiChar=^AnsiChar ;
PWideChar=^WideChar ;
Pchar=PAnsiChar ;

零結尾字串是pchar被應用最多的型式，在Object Pascal Language Guide的第15章是一篇完整的章節討論零結尾字串，在這裏就不多作介紹了。
最後要提到一個保留字nil。nil代表一個指標型態沒有指向任何地方，可適用於任何一種指標型態。

程序型態(procedural types)
程序型態是把程序(precodure)和函數(function)視為一種型態，可以宣告成變數，甚至是當成參數來傳遞。
除了省略識別字(程序名稱)外，程序型態的宣告和一般程序(函數)的宣告方式幾乎是一模一樣的。讓我們看看底下的範例:
type
Tprocedure=procedure ;
TMyCallBack=procedure(h:word) ;
TMyFunc=procedure(a,b:integer;c:float) ; stdcall ;
TMouseEvent = procedure (Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer) of object;

因為一個程序(或函數)在呼叫時，會有參數傳遞的問題，尤其是和非Delphi程式做連結時，更是要注意參數的傳遞的方式，否則就得不到正確的結果了。因為目前各種編譯器使用的參數傳遞方式不盡相同，所以在宣告程序變數時，我們也可以指定呼叫慣例來決定參數的傳遞方式，就像上例中TMyFunc的宣告指定用stdcall的呼叫慣例。可以指定的呼叫慣例共有四種: register、cdecl、pascal和stdcall。當編譯選項設定最佳化時，預設的呼叫慣例為register，若不設定最佳化則內定為pascal。
上例中，TMouseEvent在procedure後多了兩個保留字of obiect，我們稱這種型式的程序型態為方法指標(method pointers)，方法指標可以參考物件(object)中的程序或函數，若沒有加上of object我們則稱為全域程序指標(global procedure pointers)，用來參考全域的程序或函數。方法指標和全域程序指標的記錄方式不同(方法指標多了一個指標記錄物件)，二者不可混用。
事實上，程序型態也是一種指標，用來指向一個程序(函數)的位址。因此任何程序型態宣告出來的變數都可指定為nil。
要指定一個全域程序(函數)到用程序型態所宣告的變數中，全域程序(函數)必須設為遠程呼叫(far call)，可以在全域程序的後面加上保留字far，或在{$F+}狀態下編譯。另外有幾種程序和函數不能直接指定給程序變數，如: 標準程序和函數、巢狀程序和函數，以及inline程序和函數。
變動型態(variant types)
之前所介紹的各種型態，一旦宣告後，它的型態就固定不變，只有在運算時，可以利用轉型(typecast)或是函數轉換才能和不同型態的數值做運算。現在我們要介紹的這種型態，可以自動在各種型態中轉換，所以稱為變動型態。
我們用識別字variant來定義變動型態，同樣的，還是用例子來說明什麼是變動型態。
var
v1,v2,v3 : variant ;
begin
v1:=100 ; // 整數值
v2:='3.1416' ; // 字串
v3:=v1*v1*v2 ; // 字串會自動轉成實數型態後運算，結果為實數

v3:=varArrayCreate([0,2],varVariant) ; // 一維變動陣列
v3[0]:=false ; // 布林型態
V3[1]:='test' ; // 字串型態
v3[2]:=varArrayOf([101,102,103]) ; // 陣列型態

v1:=v3[2][0] // 101
v2:=v3[2][1] // 102
end ;

由前面這個例子很明顯就可以看出變動型態的特性，可以指定成不同的型態，並自動轉換成運算所需要的運算，當然，如果是無法轉換的型態，還是會產生錯誤訊息。例如把 'abc' 拿來做加法這一類的運算仍然是不允許的。
變動型態在Delphi 32位元版後才有提供，其特性整理如下:
O 一個變動型態變數使用16個位元組，包含一個位元組的型態編號(Type Code)。可以使用標準函數VarType取回變動型態的型態編號。
O 變動型態可以是下列幾種型態: 整數、實數、字串、布林、時間、陣列，以及OLE自動物件(Automation Objects)。不過陣列的使用不能直接指定一個已宣告的陣列，必須使用系統提供的函數來產生。
O 有兩個特定的變動型態數值。unassigned代表一個尚未指定數值的變動型態變數。null則表示一個未知或是沒有資料的變數。
O 變動型態變數可以和其他的型態，如整數、實數、字串、布林、時間等直接運算，變動型態會自動產生必須的轉換。
O 當變動型態變數包含一個OLE自動物件時，這個變數可以使用其屬性(properties)及方法(methods)。產生OLE自動物件的方法可以使用CreateOleObject來達成。
O 當一個變動型態變數產生時，一定是設成unassigned。
O 使用變動型態，因為需要有較多的轉換，所以會使用較多的記憶體及運算時間。
關於變動型態，Delphi提供了一系列的相關函數，在此我們只是介紹變動型態的特性，詳細的運用及相關函數說明，請參考使用手冊或線上說明(On-Line Help)。
型態間的關聯
在程式中需要是相同(identical)或相容(compatible)型態的變數，才可以互相指定、運算或當成參數傳遞。
只有當成參數傳遞時，才要求一定要相同的型態，指定或運算時只要型態相容即可。
型態相同
必須是用相同的型態識別字宣告，或是被宣告成相同型態，我們才稱為是型態相同。下面是一些例子:
type
T1=word ;
T2=word ;
T3=T2 ;        // T1, T2, T3二個型態是相同的。

T5=set of 'A'..'E' ;
T6=set of 'A'..'E' ;    // T5和T6相容，但是不相同。

var
V1, V2 : T5 ;        // V1和V2型態相同
V3 : T6 ;            // V1和V3型態不相同

型態相容
必須是相容的型態才可以放在一起運算或指定數值。在指定一個數值給變數時，除了必須是相容的型態外，還要符合指定相容(assignment compatibility)的規則。底下分別列出相容的型態和指定相容的條件:
相容的型態
O 二個相同的型態。
O 二個整數型態。
O 二個實數型態。
O 二個相同主型態的子範圍型態。
O 二個有相同數目元素的壓縮字串型態。
O 二個具有相同基礎型態的集合型態。
O 二個指向相同型態的指標。(只有設定{$T+}才成立)
O 二個傳回值型態相同且每一個對應參數的型態都相同的程序型態。
O pointer型態和任何指標型態。
O 子範圍型態和它的主型態。
O 類別型態(類別參考型態)和它的後代。
O 一個字串型態，另一個是字串或是壓縮字串或字元(char)型態。
O pchar和另一個以零為基礎的字元陣列。(只有設定{$X+}才成立)
指定相容
指定敘述，像是v1:=v2，必須符合下列其中一項條件才能成立，否則在編譯的過程中，會產生錯誤。
O v1和v2是相容的型態，且v2的數值在v1所允許的範圍內。
O v1和v2都不是且不包含檔案型態的變數。
O v1是實數變數，v2是整數變數。

關於型態的部份就介紹到這裏，若還需要更詳盡的細節，請參考Delphi的使用手冊或線上說明(On-Line Help)，可得到相關的資訊。